كيف نجعل أيقونة البرنامج بجانب الساعة , و كيف ...

PHP كود :

procedure TMain.SetBtnClick(Sender: TObject);
var
  SystrayIcon: TNotifyIconData;
begin

  Main.Visible := False;

  SystrayIcon.cbSize := SizeOf(SystrayIcon);
  SystrayIcon.Wnd := Main.handle;
  SystrayIcon.uID := 1;
  SystrayIcon.uFlags := NIF_ICON or NIF_TIP or NIF_MESSAGE;
  SystrayIcon.uCallbackMessage := WM_MOUSEMOVE;
  SystrayIcon.hIcon := Application.Icon.Handle;
  SystrayIcon.szTip := 'Sample Systray'#13'www.delphi4arab.net'#13''#13'STRELiTZIA | AT4RE';
  Shell_NotifyIcon(NIM_ADD, @SystrayIcon);
end;

كود :

uses ShellApi;
...
  private
    procedure WMTaskMsg(var Msg: TMessage); message WM_APP + 100;
    procedure WMSysCommand(var msg: TWMSysCommand); message WM_SysCommand;
...
var  MyTNA: TNotifyIconData;
...
procedure TForm1.WMSysCommand(var msg: TWMSysCommand);
begin
  if msg.CmdType and $FFF0 = SC_MINIMIZE then
    Masquer1.Click
  else
    inherited;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  with MyTNA do begin
    cbSize := SizeOf(MyTNA);
    Wnd := Handle;
    uID := UINT(Self);
    uFlags := NIF_ICON + NIF_MESSAGE + NIF_TIP;
    uCallbackMessage := WM_APP + 100;{WM_USER + 1;//Pour défini par l'utilisateur: WM_USER + $7258;}
    hIcon := Application.Icon.Handle; {Utiliser LoadIcon(HInstance, 'xxx') pour une icone dans les rescources}
    szTip := 'Hint sur l''icône';
  end;
  Shell_NotifyIcon(NIM_ADD,@MyTNA);//Application.ShowMainForm := False;
end;

procedure TForm1.WMTaskMsg(var Msg: TMessage);
var CursorPoint: TPoint;
begin
if Msg.WParam = MyTNA.uID then
  case Msg.LParam of
  WM_LBUTTONDOWN: Masquer1.Click;//Bouton gauche click
  WM_RBUTTONDOWN://Bouton droite click
    begin
    GetCursorPos(CursorPoint);
    PopupMenu1.Popup(CursorPoint.X,CursorPoint.Y);
    end;
  WM_LBUTTONDBLCLK: Afficher1.Click; //Double click bouton gauche click
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Shell_NotifyIcon(NIM_DELETE,@MyTNA);
end;

procedure TForm1.Afficher1Click(Sender: TObject);
var  HndOwner: THandle;
begin
  //Afficher la fenêtre Form1
  SendMessage(Self.Handle, WM_SYSCOMMAND, SC_RESTORE, 0);
  ShowWindow(Self.Handle, SW_SHOW);
  SetForegroundWindow(Self.Handle);
  //Afficher dans la barre des tâches
  HndOwner := GetWindow(Self.Handle, GW_OWNER);
  SendMessage(HndOwner, WM_SYSCOMMAND, SC_RESTORE, 0);
  ShowWindow(HndOwner, SW_SHOW);
end;

procedure TForm1.Masquer1Click(Sender: TObject);
begin
  ShowWindow(Self.Handle, SW_HIDE);//Masquer Form1
  ShowWindow(GetWindow(Self.Handle, GW_OWNER), SW_HIDE);//Masquer du TaskBar
end;

procedure TForm1.Quitter1Click(Sender: TObject);
begin
  Close;
end;